특정 행에서 아래로 열을 요약합니다.

특정 행에서 아래로 열을 요약합니다.

간단해 보이지만, Excel 공식에서 컬럼의 마지막까지 범위를 정의하는 방법을 찾을 수 없습니다.

예를 들어, 이 방정식 SUM(C:C)을 사용하여 C열에 있는 모든 숫자를 합할 수 있습니다.그러나 페이지 상단에 제목과 열 머리글이 있기 때문에 6행부터 범위를 시작하고 싶습니다.SUM(C6:C)이 할 줄 알았는데, 엑셀에서는 안 돼요.

이것은 필수이기 때문에 향후 문서에 몇 줄의 데이터를 추가해도 항상 SUM이 맞습니다.

감사해요.

=Sum(C:C)-Sum(C1:C5)

모든 값을 합산한 다음 필요하지 않은 셀의 값 합계를 제거합니다. 휘발성 오프셋, 간접 또는 배열은 필요하지 않습니다.

이 방법이 마음에 들지 않으면 재미삼아 다음 방법을 사용할 수도 있습니다.

=SUM($C$6:INDEX($C:$C,MATCH(9.99999999999999E+307,$C:$C))

위의 공식은 숫자의 일치가 검출된 C:C의 마지막 셀을 C6부터 C:C까지만 합산합니다.이것도 비휘발성이지만 더 비싸고 엉성하다고 생각합니다.어차피 이게 더 좋을지도 모르니까 추가해놨어

사용할 수 있는 열의 마지막 텍스트 값을 사용하여 텍스트에 대한 카운트A와 같은 기능을 수행하려는 경우.

=COUNTIF(C6:INDEX($C:$C,MATCH(REPT("Z",255),$C:$C)),"T")

다음과 같은 다른 조합도 사용할 수 있습니다.

=Sum($C$6:$C$65536) 

또는

=CountIF($C$6:$C$65536,"T") 

위의 내용은 Excel 2003 이하에서 사용자가 요구하는 내용을 수행합니다.

=Sum($C$6:$C$1048576) 

또는

=CountIF($C$6:$C$1048576,"T")

둘 다 Excel 2007+에서 사용할 수 있습니까?

위의 모든 함수는 마지막 값 아래의 모든 빈 값을 무시합니다.

이 방법이 가장 쉬운 방법인 것 같습니다(그러나 가장 견고하지는 않습니다).Excel에서 지정한 대로 6행부터 최대 허용 행 번호까지 합계를 계산합니다.이 사이트에 따르면 현재 최대값은 1048576이므로 다음 사항이 적합합니다.

=sum(c6:c1048576)

보다 견고한 솔루션에 대해서는, 그 외의 회답을 참조해 주세요.

모두 합병증을 좋아하는 것 같네요열을 클릭하기만 하면(열 전체를 선택하려면) Ctrl 키를 누른 상태에서 제외할 셀(예: C1 ~ C5)을 클릭합니다.이제 셀을 시작하지 않고 전체 열 C(시트 끝 오른쪽)를 선택했습니다.여기서 해야 할 일은 오른쪽 버튼을 클릭하여 선택한 이름을 정의하는 것입니다(예: asdf).공식에서는 SUM(asdf)을 사용합니다.그리고 이제 넌 끝났어행운을 빌어요

항상 가장 쉬운 방법을 찾아라;)

OFFSET()을 사용하는 것이 좋습니다.이 함수는 셀이 변경될 때마다 재계산되는 휘발성 함수입니다.다이나믹하고 재사용 가능한 솔루션입니다.

=OFFSET($COL:$COL, ROW(), 1, 1048576 - ROW(), 1)

여기서 $COL은 조작할 컬럼의 문자이며 ROW()는 이 수식을 포함하는 셀과 같은 행을 동적으로 선택하는 행 함수입니다.ROW() 함수를 정적 번호($ROW)로 대체할 수도 있습니다.

=OFFSET($COL:$COL, $ROW, 1, 1048576 - $ROW, 1)

1048576의 명명된 상수를 'maxRows'로 정의하면 공식을 더욱 정리할 수 있습니다.이 작업은 공식 탭의 '이름 정의' 메뉴에서 수행할 수 있습니다.

=OFFSET($COL:$COL, $ROW, 1, maxRows - $ROW, 1)

간단한 예: C6에서 C열의 끝까지 합계를 구하려면 다음을 수행할 수 있습니다.

=SUM(OFFSET(C:C, 6, 1, maxRows - 6, 1))

또는 =SUM(OFFSET(C:C, ROW(), 1, maxRows - ROW(), 1)

이와 같은 것이 나에게는 효과가 있었습니다(해당하는 경우 Excel 2013에서는 8행부터 8행까지 C열과 D열을 참조).

=SUMIFS(INDIRECT(ADDRESS(ROW(D$8), COLUMN())&":"&ADDRESS(ROWS($C:$C), COLUMN())),INDIRECT("C$8:C"&ROWS($C:$C)),$C$2)

언급URL : https://stackoverflow.com/questions/21286362/sum-up-a-column-from-a-specific-row-down